home *** CD-ROM | disk | FTP | other *** search
/ The Arsenal Files 8 / The Arsenal Files Collection #8 (Arsenal Computer) (1996).ISO / g_quake / compass.zip / WEAPONS.QC < prev   
Text File  |  1996-09-19  |  24KB  |  1,228 lines
  1. /*
  2. */
  3. void (entity targ, entity inflictor, entity attacker, float damage) T_Damage;
  4. void () player_run;
  5. void(entity bomb, entity attacker, float rad, entity ignore) T_RadiusDamage;
  6. void(vector org, vector vel, float damage) SpawnBlood;
  7. void() SuperDamageSound;
  8. void() DisplayCompass;
  9.  
  10.  
  11. // called by worldspawn
  12. void() W_Precache =
  13. {
  14.     precache_sound ("weapons/r_exp3.wav");    // new rocket explosion
  15.     precache_sound ("weapons/rocket1i.wav");    // spike gun
  16.     precache_sound ("weapons/sgun1.wav");
  17.     precache_sound ("weapons/guncock.wav");    // player shotgun
  18.     precache_sound ("weapons/ric1.wav");    // ricochet (used in c code)
  19.     precache_sound ("weapons/ric2.wav");    // ricochet (used in c code)
  20.     precache_sound ("weapons/ric3.wav");    // ricochet (used in c code)
  21.     precache_sound ("weapons/spike2.wav");    // super spikes
  22.     precache_sound ("weapons/tink1.wav");    // spikes tink (used in c code)
  23.     precache_sound ("weapons/grenade.wav");    // grenade launcher
  24.     precache_sound ("weapons/bounce.wav");        // grenade bounce
  25.     precache_sound ("weapons/shotgn2.wav");    // super shotgun
  26. };
  27.  
  28. float() crandom =
  29. {
  30.     return 2*(random() - 0.5);
  31. };
  32.  
  33. /*
  34. ================
  35. W_FireAxe
  36. ================
  37. */
  38. void() W_FireAxe =
  39. {
  40.     local    vector    source;
  41.     local    vector    org;
  42.  
  43.     source = self.origin + '0 0 16';
  44.     traceline (source, source + v_forward*64, FALSE, self);
  45.     if (trace_fraction == 1.0)
  46.         return;
  47.     
  48.     org = trace_endpos - v_forward*4;
  49.  
  50.     if (trace_ent.takedamage)
  51.     {
  52.         trace_ent.axhitme = 1;
  53.         SpawnBlood (org, '0 0 0', 20);
  54.         T_Damage (trace_ent, self, self, 20);
  55.     }
  56.     else
  57.     {    // hit wall
  58.         sound (self, CHAN_WEAPON, "player/axhit2.wav", 1, ATTN_NORM);
  59.         WriteByte (MSG_BROADCAST, SVC_TEMPENTITY);
  60.         WriteByte (MSG_BROADCAST, TE_GUNSHOT);
  61.         WriteCoord (MSG_BROADCAST, org_x);
  62.         WriteCoord (MSG_BROADCAST, org_y);
  63.         WriteCoord (MSG_BROADCAST, org_z);
  64.     }
  65. };
  66.  
  67.  
  68. //============================================================================
  69.  
  70.  
  71. vector() wall_velocity =
  72. {
  73.     local vector    vel;
  74.     
  75.     vel = normalize (self.velocity);
  76.     vel = normalize(vel + v_up*(random()- 0.5) + v_right*(random()- 0.5));
  77.     vel = vel + 2*trace_plane_normal;
  78.     vel = vel * 200;
  79.     
  80.     return vel;
  81. };
  82.  
  83.  
  84. /*
  85. ================
  86. SpawnMeatSpray
  87. ================
  88. */
  89. void(vector org, vector vel) SpawnMeatSpray =
  90. {
  91.     local    entity missile, mpuff;
  92.     local    vector    org;
  93.  
  94.     missile = spawn ();
  95.     missile.owner = self;
  96.     missile.movetype = MOVETYPE_BOUNCE;
  97.     missile.solid = SOLID_NOT;
  98.  
  99.     makevectors (self.angles);
  100.  
  101.     missile.velocity = vel;
  102.     missile.velocity_z = missile.velocity_z + 250 + 50*random();
  103.  
  104.     missile.avelocity = '3000 1000 2000';
  105.     
  106. // set missile duration
  107.     missile.nextthink = time + 1;
  108.     missile.think = SUB_Remove;
  109.  
  110.     setmodel (missile, "progs/zom_gib.mdl");
  111.     setsize (missile, '0 0 0', '0 0 0');        
  112.     setorigin (missile, org);
  113. };
  114.  
  115. /*
  116. ================
  117. SpawnBlood
  118. ================
  119. */
  120. void(vector org, vector vel, float damage) SpawnBlood =
  121. {
  122.     particle (org, vel*0.1, 73, damage*2);
  123. };
  124.  
  125. /*
  126. ================
  127. spawn_touchblood
  128. ================
  129. */
  130. void(float damage) spawn_touchblood =
  131. {
  132.     local vector    vel;
  133.  
  134.     vel = wall_velocity () * 0.2;
  135.     SpawnBlood (self.origin + vel*0.01, vel, damage);
  136. };
  137.  
  138.  
  139. /*
  140. ================
  141. SpawnChunk
  142. ================
  143. */
  144. void(vector org, vector vel) SpawnChunk =
  145. {
  146.     particle (org, vel*0.02, 0, 10);
  147. };
  148.  
  149. /*
  150. ==============================================================================
  151.  
  152. MULTI-DAMAGE
  153.  
  154. Collects multiple small damages into a single damage
  155.  
  156. ==============================================================================
  157. */
  158.  
  159. entity    multi_ent;
  160. float    multi_damage;
  161.  
  162. void() ClearMultiDamage =
  163. {
  164.     multi_ent = world;
  165.     multi_damage = 0;
  166. };
  167.  
  168. void() ApplyMultiDamage =
  169. {
  170.     if (!multi_ent)
  171.         return;
  172.     T_Damage (multi_ent, self, self, multi_damage);
  173. };
  174.  
  175. void(entity hit, float damage) AddMultiDamage =
  176. {
  177.     if (!hit)
  178.         return;
  179.     
  180.     if (hit != multi_ent)
  181.     {
  182.         ApplyMultiDamage ();
  183.         multi_damage = damage;
  184.         multi_ent = hit;
  185.     }
  186.     else
  187.         multi_damage = multi_damage + damage;
  188. };
  189.  
  190. /*
  191. ==============================================================================
  192.  
  193. BULLETS
  194.  
  195. ==============================================================================
  196. */
  197.  
  198. /*
  199. ================
  200. TraceAttack
  201. ================
  202. */
  203. void(float damage, vector dir) TraceAttack =
  204. {
  205.     local    vector    vel, org;
  206.     
  207.     vel = normalize(dir + v_up*crandom() + v_right*crandom());
  208.     vel = vel + 2*trace_plane_normal;
  209.     vel = vel * 200;
  210.  
  211.     org = trace_endpos - dir*4;
  212.  
  213.     if (trace_ent.takedamage)
  214.     {
  215.         SpawnBlood (org, vel*0.2, damage);
  216.         AddMultiDamage (trace_ent, damage);
  217.     }
  218.     else
  219.     {
  220.         WriteByte (MSG_BROADCAST, SVC_TEMPENTITY);
  221.         WriteByte (MSG_BROADCAST, TE_GUNSHOT);
  222.         WriteCoord (MSG_BROADCAST, org_x);
  223.         WriteCoord (MSG_BROADCAST, org_y);
  224.         WriteCoord (MSG_BROADCAST, org_z);
  225.     }
  226. };
  227.  
  228. /*
  229. ================
  230. FireBullets
  231.  
  232. Used by shotgun, super shotgun, and enemy soldier firing
  233. Go to the trouble of combining multiple pellets into a single damage call.
  234. ================
  235. */
  236. void(float shotcount, vector dir, vector spread) FireBullets =
  237. {
  238.     local    vector direction;
  239.     local    vector    src;
  240.     
  241.     makevectors(self.v_angle);
  242.  
  243.     src = self.origin + v_forward*10;
  244.     src_z = self.absmin_z + self.size_z * 0.7;
  245.  
  246.     ClearMultiDamage ();
  247.     while (shotcount > 0)
  248.     {
  249.         direction = dir + crandom()*spread_x*v_right + crandom()*spread_y*v_up;
  250.  
  251.         traceline (src, src + direction*2048, FALSE, self);
  252.         if (trace_fraction != 1.0)
  253.             TraceAttack (4, direction);
  254.  
  255.         shotcount = shotcount - 1;
  256.     }
  257.     ApplyMultiDamage ();
  258. };
  259.  
  260. /*
  261. ================
  262. W_FireShotgun
  263. ================
  264. */
  265. void() W_FireShotgun =
  266. {
  267.     local vector dir;
  268.  
  269.     sound (self, CHAN_WEAPON, "weapons/guncock.wav", 1, ATTN_NORM);    
  270.  
  271.     self.punchangle_x = -2;
  272.     
  273.     self.currentammo = self.ammo_shells = self.ammo_shells - 1;
  274.     dir = aim (self, 100000);
  275.     FireBullets (6, dir, '0.04 0.04 0');
  276. };
  277.  
  278.  
  279. /*
  280. ================
  281. W_FireSuperShotgun
  282. ================
  283. */
  284. void() W_FireSuperShotgun =
  285. {
  286.     local vector dir;
  287.  
  288.     if (self.currentammo == 1)
  289.     {
  290.         W_FireShotgun ();
  291.         return;
  292.     }
  293.         
  294.     sound (self ,CHAN_WEAPON, "weapons/shotgn2.wav", 1, ATTN_NORM);    
  295.  
  296.     self.punchangle_x = -4;
  297.     
  298.     self.currentammo = self.ammo_shells = self.ammo_shells - 2;
  299.     dir = aim (self, 100000);
  300.     FireBullets (14, dir, '0.14 0.08 0');
  301. };
  302.  
  303.  
  304. /*
  305. ==============================================================================
  306.  
  307. ROCKETS
  308.  
  309. ==============================================================================
  310. */
  311.  
  312. void()    s_explode1    =    [0,        s_explode2] {};
  313. void()    s_explode2    =    [1,        s_explode3] {};
  314. void()    s_explode3    =    [2,        s_explode4] {};
  315. void()    s_explode4    =    [3,        s_explode5] {};
  316. void()    s_explode5    =    [4,        s_explode6] {};
  317. void()    s_explode6    =    [5,        SUB_Remove] {};
  318.  
  319. void() BecomeExplosion =
  320. {
  321.     self.movetype = MOVETYPE_NONE;
  322.     self.velocity = '0 0 0';
  323.     self.touch = SUB_Null;
  324.     setmodel (self, "progs/s_explod.spr");
  325.     self.solid = SOLID_NOT;
  326.     s_explode1 ();
  327. };
  328.  
  329. void() T_MissileTouch =
  330. {
  331.     local float    damg;
  332.  
  333.     if (other == self.owner)
  334.         return;        // don't explode on owner
  335.  
  336.     if (pointcontents(self.origin) == CONTENT_SKY)
  337.     {
  338.         remove(self);
  339.         return;
  340.     }
  341.  
  342.     damg = 100 + random()*20;
  343.     
  344.     if (other.health)
  345.     {
  346.         if (other.classname == "monster_shambler")
  347.             damg = damg * 0.5;    // mostly immune
  348.         T_Damage (other, self, self.owner, damg );
  349.     }
  350.  
  351.     // don't do radius damage to the other, because all the damage
  352.     // was done in the impact
  353.     T_RadiusDamage (self, self.owner, 120, other);
  354.  
  355. //    sound (self, CHAN_WEAPON, "weapons/r_exp3.wav", 1, ATTN_NORM);
  356.     self.origin = self.origin - 8*normalize(self.velocity);
  357.  
  358.     WriteByte (MSG_BROADCAST, SVC_TEMPENTITY);
  359.     WriteByte (MSG_BROADCAST, TE_EXPLOSION);
  360.     WriteCoord (MSG_BROADCAST, self.origin_x);
  361.     WriteCoord (MSG_BROADCAST, self.origin_y);
  362.     WriteCoord (MSG_BROADCAST, self.origin_z);
  363.  
  364.     BecomeExplosion ();
  365. };
  366.  
  367.  
  368.  
  369. /*
  370. ================
  371. W_FireRocket
  372. ================
  373. */
  374. void() W_FireRocket =
  375. {
  376.     local    entity missile, mpuff;
  377.     
  378.     self.currentammo = self.ammo_rockets = self.ammo_rockets - 1;
  379.     
  380.     sound (self, CHAN_WEAPON, "weapons/sgun1.wav", 1, ATTN_NORM);
  381.  
  382.     self.punchangle_x = -2;
  383.  
  384.     missile = spawn ();
  385.     missile.owner = self;
  386.     missile.movetype = MOVETYPE_FLYMISSILE;
  387.     missile.solid = SOLID_BBOX;
  388.         
  389. // set missile speed    
  390.  
  391.     makevectors (self.v_angle);
  392.     missile.velocity = aim(self, 1000);
  393.     missile.velocity = missile.velocity * 1000;
  394.     missile.angles = vectoangles(missile.velocity);
  395.     
  396.     missile.touch = T_MissileTouch;
  397.     
  398. // set missile duration
  399.     missile.nextthink = time + 5;
  400.     missile.think = SUB_Remove;
  401.  
  402.     setmodel (missile, "progs/missile.mdl");
  403.     setsize (missile, '0 0 0', '0 0 0');        
  404.     setorigin (missile, self.origin + v_forward*8 + '0 0 16');
  405. };
  406.  
  407. /*
  408. ===============================================================================
  409.  
  410. LIGHTNING
  411.  
  412. ===============================================================================
  413. */
  414.  
  415. /*
  416. =================
  417. LightningDamage
  418. =================
  419. */
  420. void(vector p1, vector p2, entity from, float damage) LightningDamage =
  421. {
  422.     local entity        e1, e2;
  423.     local vector        f;
  424.     
  425.     f = p2 - p1;
  426.     normalize (f);
  427.     f_x = 0 - f_y;
  428.     f_y = f_x;
  429.     f_z = 0;
  430.     f = f*16;
  431.  
  432.     e1 = e2 = world;
  433.  
  434.     traceline (p1, p2, FALSE, self);
  435.     if (trace_ent.takedamage)
  436.     {
  437.         particle (trace_endpos, '0 0 100', 225, damage*4);
  438.         T_Damage (trace_ent, from, from, damage);
  439.         if (self.classname == "player")
  440.         {
  441.             if (other.classname == "player")
  442.                 trace_ent.velocity_z = trace_ent.velocity_z + 400;
  443.         }
  444.     }
  445.     e1 = trace_ent;
  446.  
  447.     traceline (p1 + f, p2 + f, FALSE, self);
  448.     if (trace_ent != e1 && trace_ent.takedamage)
  449.     {
  450.         particle (trace_endpos, '0 0 100', 225, damage*4);
  451.         T_Damage (trace_ent, from, from, damage);
  452.     }
  453.     e2 = trace_ent;
  454.  
  455.     traceline (p1 - f, p2 - f, FALSE, self);
  456.     if (trace_ent != e1 && trace_ent != e2 && trace_ent.takedamage)
  457.     {
  458.         particle (trace_endpos, '0 0 100', 225, damage*4);
  459.         T_Damage (trace_ent, from, from, damage);
  460.     }
  461. };
  462.  
  463.  
  464. void() W_FireLightning =
  465. {
  466.     local    vector        org;
  467.  
  468.     if (self.ammo_cells < 1)
  469.     {
  470.         self.weapon = W_BestWeapon ();
  471.         W_SetCurrentAmmo ();
  472.         return;
  473.     }
  474.  
  475. // explode if under water
  476.     if (self.waterlevel > 1)
  477.     {
  478.         T_RadiusDamage (self, self, 35*self.ammo_cells, world);
  479.         self.ammo_cells = 0;
  480.         W_SetCurrentAmmo ();
  481.         return;
  482.     }
  483.  
  484.     if (self.t_width < time)
  485.     {
  486.         sound (self, CHAN_WEAPON, "weapons/lhit.wav", 1, ATTN_NORM);
  487.         self.t_width = time + 0.6;
  488.     }
  489.     self.punchangle_x = -2;
  490.  
  491.     self.currentammo = self.ammo_cells = self.ammo_cells - 1;
  492.  
  493.     org = self.origin + '0 0 16';
  494.     
  495.     traceline (org, org + v_forward*600, TRUE, self);
  496.  
  497.     WriteByte (MSG_BROADCAST, SVC_TEMPENTITY);
  498.     WriteByte (MSG_BROADCAST, TE_LIGHTNING2);
  499.     WriteEntity (MSG_BROADCAST, self);
  500.     WriteCoord (MSG_BROADCAST, org_x);
  501.     WriteCoord (MSG_BROADCAST, org_y);
  502.     WriteCoord (MSG_BROADCAST, org_z);
  503.     WriteCoord (MSG_BROADCAST, trace_endpos_x);
  504.     WriteCoord (MSG_BROADCAST, trace_endpos_y);
  505.     WriteCoord (MSG_BROADCAST, trace_endpos_z);
  506.  
  507.     LightningDamage (self.origin, trace_endpos + v_forward*4, self, 30);
  508. };
  509.  
  510.  
  511. //=============================================================================
  512.  
  513.  
  514. void() GrenadeExplode =
  515. {
  516.     T_RadiusDamage (self, self.owner, 120, world);
  517.  
  518.     WriteByte (MSG_BROADCAST, SVC_TEMPENTITY);
  519.     WriteByte (MSG_BROADCAST, TE_EXPLOSION);
  520.     WriteCoord (MSG_BROADCAST, self.origin_x);
  521.     WriteCoord (MSG_BROADCAST, self.origin_y);
  522.     WriteCoord (MSG_BROADCAST, self.origin_z);
  523.  
  524.     BecomeExplosion ();
  525. };
  526.  
  527. void() GrenadeTouch =
  528. {
  529.     if (other == self.owner)
  530.         return;        // don't explode on owner
  531.     if (other.takedamage == DAMAGE_AIM)
  532.     {
  533.         GrenadeExplode();
  534.         return;
  535.     }
  536.     sound (self, CHAN_WEAPON, "weapons/bounce.wav", 1, ATTN_NORM);    // bounce sound
  537.     if (self.velocity == '0 0 0')
  538.         self.avelocity = '0 0 0';
  539. };
  540.  
  541. /*
  542. ================
  543. W_FireGrenade
  544. ================
  545. */
  546. void() W_FireGrenade =
  547. {
  548.     local    entity missile, mpuff;
  549.     
  550.     self.currentammo = self.ammo_rockets = self.ammo_rockets - 1;
  551.     
  552.     sound (self, CHAN_WEAPON, "weapons/grenade.wav", 1, ATTN_NORM);
  553.  
  554.     self.punchangle_x = -2;
  555.  
  556.     missile = spawn ();
  557.     missile.owner = self;
  558.     missile.movetype = MOVETYPE_BOUNCE;
  559.     missile.solid = SOLID_BBOX;
  560.     missile.classname = "grenade";
  561.         
  562. // set missile speed    
  563.  
  564.     makevectors (self.v_angle);
  565.  
  566.     if (self.v_angle_x)
  567.         missile.velocity = v_forward*600 + v_up * 200 + crandom()*v_right*10 + crandom()*v_up*10;
  568.     else
  569.     {
  570.         missile.velocity = aim(self, 10000);
  571.         missile.velocity = missile.velocity * 600;
  572.         missile.velocity_z = 200;
  573.     }
  574.  
  575.     missile.avelocity = '300 300 300';
  576.  
  577.     missile.angles = vectoangles(missile.velocity);
  578.     
  579.     missile.touch = GrenadeTouch;
  580.     
  581. // set missile duration
  582.     missile.nextthink = time + 2.5;
  583.     missile.think = GrenadeExplode;
  584.  
  585.     setmodel (missile, "progs/grenade.mdl");
  586.     setsize (missile, '0 0 0', '0 0 0');        
  587.     setorigin (missile, self.origin);
  588. };
  589.  
  590.  
  591. //=============================================================================
  592.  
  593. void() spike_touch;
  594. void() superspike_touch;
  595.  
  596.  
  597. /*
  598. ===============
  599. launch_spike
  600.  
  601. Used for both the player and the ogre
  602. ===============
  603. */
  604. void(vector org, vector dir) launch_spike =
  605. {
  606.     newmis = spawn ();
  607.     newmis.owner = self;
  608.     newmis.movetype = MOVETYPE_FLYMISSILE;
  609.     newmis.solid = SOLID_BBOX;
  610.  
  611.     newmis.angles = vectoangles(dir);
  612.     
  613.     newmis.touch = spike_touch;
  614.     newmis.classname = "spike";
  615.     newmis.think = SUB_Remove;
  616.     newmis.nextthink = time + 6;
  617.     setmodel (newmis, "progs/spike.mdl");
  618.     setsize (newmis, VEC_ORIGIN, VEC_ORIGIN);        
  619.     setorigin (newmis, org);
  620.  
  621.     newmis.velocity = dir * 1000;
  622. };
  623.  
  624. void() W_FireSuperSpikes =
  625. {
  626.     local vector    dir;
  627.     local entity    old;
  628.     
  629.     sound (self, CHAN_WEAPON, "weapons/spike2.wav", 1, ATTN_NORM);
  630.     self.attack_finished = time + 0.2;
  631.     self.currentammo = self.ammo_nails = self.ammo_nails - 2;
  632.     dir = aim (self, 1000);
  633.     launch_spike (self.origin + '0 0 16', dir);
  634.     newmis.touch = superspike_touch;
  635.     setmodel (newmis, "progs/s_spike.mdl");
  636.     setsize (newmis, VEC_ORIGIN, VEC_ORIGIN);        
  637.     self.punchangle_x = -2;
  638. };
  639.  
  640. void(float ox) W_FireSpikes =
  641. {
  642.     local vector    dir;
  643.     local entity    old;
  644.     
  645.     makevectors (self.v_angle);
  646.     
  647.     if (self.ammo_nails >= 2 && self.weapon == IT_SUPER_NAILGUN)
  648.     {
  649.         W_FireSuperSpikes ();
  650.         return;
  651.     }
  652.  
  653.     if (self.ammo_nails < 1)
  654.     {
  655.         self.weapon = W_BestWeapon ();
  656.         W_SetCurrentAmmo ();
  657.         return;
  658.     }
  659.  
  660.     sound (self, CHAN_WEAPON, "weapons/rocket1i.wav", 1, ATTN_NORM);
  661.     self.attack_finished = time + 0.2;
  662.     self.currentammo = self.ammo_nails = self.ammo_nails - 1;
  663.     dir = aim (self, 1000);
  664.     launch_spike (self.origin + '0 0 16' + v_right*ox, dir);
  665.  
  666.     self.punchangle_x = -2;
  667. };
  668.  
  669.  
  670.  
  671. .float hit_z;
  672. void() spike_touch =
  673. {
  674. local float rand;
  675.     if (other == self.owner)
  676.         return;
  677.  
  678.     if (other.solid == SOLID_TRIGGER)
  679.         return;    // trigger field, do nothing
  680.  
  681.     if (pointcontents(self.origin) == CONTENT_SKY)
  682.     {
  683.         remove(self);
  684.         return;
  685.     }
  686.     
  687. // hit something that bleeds
  688.     if (other.takedamage)
  689.     {
  690.         spawn_touchblood (9);
  691.         T_Damage (other, self, self.owner, 9);
  692.     }
  693.     else
  694.     {
  695.         WriteByte (MSG_BROADCAST, SVC_TEMPENTITY);
  696.         
  697.         if (self.classname == "wizspike")
  698.             WriteByte (MSG_BROADCAST, TE_WIZSPIKE);
  699.         else if (self.classname == "knightspike")
  700.             WriteByte (MSG_BROADCAST, TE_KNIGHTSPIKE);
  701.         else
  702.             WriteByte (MSG_BROADCAST, TE_SPIKE);
  703.         WriteCoord (MSG_BROADCAST, self.origin_x);
  704.         WriteCoord (MSG_BROADCAST, self.origin_y);
  705.         WriteCoord (MSG_BROADCAST, self.origin_z);
  706.     }
  707.  
  708.     remove(self);
  709.  
  710. };
  711.  
  712. void() superspike_touch =
  713. {
  714. local float rand;
  715.     if (other == self.owner)
  716.         return;
  717.  
  718.     if (other.solid == SOLID_TRIGGER)
  719.         return;    // trigger field, do nothing
  720.  
  721.     if (pointcontents(self.origin) == CONTENT_SKY)
  722.     {
  723.         remove(self);
  724.         return;
  725.     }
  726.     
  727. // hit something that bleeds
  728.     if (other.takedamage)
  729.     {
  730.         spawn_touchblood (18);
  731.         T_Damage (other, self, self.owner, 18);
  732.     }
  733.     else
  734.     {
  735.         WriteByte (MSG_BROADCAST, SVC_TEMPENTITY);
  736.         WriteByte (MSG_BROADCAST, TE_SUPERSPIKE);
  737.         WriteCoord (MSG_BROADCAST, self.origin_x);
  738.         WriteCoord (MSG_BROADCAST, self.origin_y);
  739.         WriteCoord (MSG_BROADCAST, self.origin_z);
  740.     }
  741.  
  742.     remove(self);
  743.  
  744. };
  745.  
  746.  
  747. /*
  748. ===============================================================================
  749.  
  750. PLAYER WEAPON USE
  751.  
  752. ===============================================================================
  753. */
  754.  
  755. void() W_SetCurrentAmmo =
  756. {
  757.     player_run ();        // get out of any weapon firing states
  758.  
  759.     self.items = self.items - ( self.items & (IT_SHELLS | IT_NAILS | IT_ROCKETS | IT_CELLS) );
  760.     
  761.     if (self.weapon == IT_AXE)
  762.     {
  763.         self.currentammo = 0;
  764.         self.weaponmodel = "progs/v_axe.mdl";
  765.         self.weaponframe = 0;
  766.     }
  767.     else if (self.weapon == IT_SHOTGUN)
  768.     {
  769.         self.currentammo = self.ammo_shells;
  770.         self.weaponmodel = "progs/v_shot.mdl";
  771.         self.weaponframe = 0;
  772.         self.items = self.items | IT_SHELLS;
  773.     }
  774.     else if (self.weapon == IT_SUPER_SHOTGUN)
  775.     {
  776.         self.currentammo = self.ammo_shells;
  777.         self.weaponmodel = "progs/v_shot2.mdl";
  778.         self.weaponframe = 0;
  779.         self.items = self.items | IT_SHELLS;
  780.     }
  781.     else if (self.weapon == IT_NAILGUN)
  782.     {
  783.         self.currentammo = self.ammo_nails;
  784.         self.weaponmodel = "progs/v_nail.mdl";
  785.         self.weaponframe = 0;
  786.         self.items = self.items | IT_NAILS;
  787.     }
  788.     else if (self.weapon == IT_SUPER_NAILGUN)
  789.     {
  790.         self.currentammo = self.ammo_nails;
  791.         self.weaponmodel = "progs/v_nail2.mdl";
  792.         self.weaponframe = 0;
  793.         self.items = self.items | IT_NAILS;
  794.     }
  795.     else if (self.weapon == IT_GRENADE_LAUNCHER)
  796.     {
  797.         self.currentammo = self.ammo_rockets;
  798.         self.weaponmodel = "progs/v_rock.mdl";
  799.         self.weaponframe = 0;
  800.         self.items = self.items | IT_ROCKETS;
  801.     }
  802.     else if (self.weapon == IT_ROCKET_LAUNCHER)
  803.     {
  804.         self.currentammo = self.ammo_rockets;
  805.         self.weaponmodel = "progs/v_rock2.mdl";
  806.         self.weaponframe = 0;
  807.         self.items = self.items | IT_ROCKETS;
  808.     }
  809.     else if (self.weapon == IT_LIGHTNING)
  810.     {
  811.         self.currentammo = self.ammo_cells;
  812.         self.weaponmodel = "progs/v_light.mdl";
  813.         self.weaponframe = 0;
  814.         self.items = self.items | IT_CELLS;
  815.     }
  816.     else
  817.     {
  818.         self.currentammo = 0;
  819.         self.weaponmodel = "";
  820.         self.weaponframe = 0;
  821.     }
  822. };
  823.  
  824. float() W_BestWeapon =
  825. {
  826.     local    float    it;
  827.     
  828.     it = self.items;
  829.  
  830.     if(self.ammo_cells >= 1 && (it & IT_LIGHTNING) )
  831.         return IT_LIGHTNING;
  832.     else if(self.ammo_nails >= 2 && (it & IT_SUPER_NAILGUN) )
  833.         return IT_SUPER_NAILGUN;
  834.     else if(self.ammo_shells >= 2 && (it & IT_SUPER_SHOTGUN) )
  835.         return IT_SUPER_SHOTGUN;
  836.     else if(self.ammo_nails >= 1 && (it & IT_NAILGUN) )
  837.         return IT_NAILGUN;
  838.     else if(self.ammo_shells >= 1 && (it & IT_SHOTGUN) )
  839.         return IT_SHOTGUN;
  840.         
  841. /*
  842.     if(self.ammo_rockets >= 1 && (it & IT_ROCKET_LAUNCHER) )
  843.         return IT_ROCKET_LAUNCHER;
  844.     else if(self.ammo_rockets >= 1 && (it & IT_GRENADE_LAUNCHER) )
  845.         return IT_GRENADE_LAUNCHER;
  846.  
  847. */
  848.  
  849.     return IT_AXE;
  850. };
  851.  
  852. float() W_CheckNoAmmo =
  853. {
  854.     if (self.currentammo > 0)
  855.         return TRUE;
  856.  
  857.     if (self.weapon == IT_AXE)
  858.         return TRUE;
  859.     
  860.     self.weapon = W_BestWeapon ();
  861.  
  862.     W_SetCurrentAmmo ();
  863.     
  864. // drop the weapon down
  865.     return FALSE;
  866. };
  867.  
  868. /*
  869. ============
  870. W_Attack
  871.  
  872. An attack impulse can be triggered now
  873. ============
  874. */
  875. void()    player_axe1;
  876. void()    player_axeb1;
  877. void()    player_axec1;
  878. void()    player_axed1;
  879. void()    player_shot1;
  880. void()    player_nail1;
  881. void()    player_light1;
  882. void()    player_rocket1;
  883.  
  884. void() W_Attack =
  885. {
  886.     local    float    r;
  887.  
  888.     if (!W_CheckNoAmmo ())
  889.         return;
  890.  
  891.     makevectors    (self.v_angle);            // calculate forward angle for velocity
  892.     self.show_hostile = time + 1;    // wake monsters up
  893.  
  894.     if (self.weapon == IT_AXE)
  895.     {
  896.         sound (self, CHAN_WEAPON, "weapons/ax1.wav", 1, ATTN_NORM);
  897.         r = random();
  898.         if (r < 0.25)
  899.             player_axe1 ();
  900.         else if (r<0.5)
  901.             player_axeb1 ();
  902.         else if (r<0.75)
  903.             player_axec1 ();
  904.         else
  905.             player_axed1 ();
  906.         self.attack_finished = time + 0.5;
  907.     }
  908.     else if (self.weapon == IT_SHOTGUN)
  909.     {
  910.         player_shot1 ();
  911.         W_FireShotgun ();
  912.         self.attack_finished = time + 0.5;
  913.     }
  914.     else if (self.weapon == IT_SUPER_SHOTGUN)
  915.     {
  916.         player_shot1 ();
  917.         W_FireSuperShotgun ();
  918.         self.attack_finished = time + 0.7;
  919.     }
  920.     else if (self.weapon == IT_NAILGUN)
  921.     {
  922.         player_nail1 ();
  923.     }
  924.     else if (self.weapon == IT_SUPER_NAILGUN)
  925.     {
  926.         player_nail1 ();
  927.     }
  928.     else if (self.weapon == IT_GRENADE_LAUNCHER)
  929.     {
  930.         player_rocket1();
  931.         W_FireGrenade();
  932.         self.attack_finished = time + 0.6;
  933.     }
  934.     else if (self.weapon == IT_ROCKET_LAUNCHER)
  935.     {
  936.         player_rocket1();
  937.         W_FireRocket();
  938.         self.attack_finished = time + 0.8;
  939.     }
  940.     else if (self.weapon == IT_LIGHTNING)
  941.     {
  942.         player_light1();
  943.         self.attack_finished = time + 0.1;
  944.         sound (self, CHAN_AUTO, "weapons/lstart.wav", 1, ATTN_NORM);
  945.     }
  946. };
  947.  
  948. /*
  949. ============
  950. W_ChangeWeapon
  951.  
  952. ============
  953. */
  954. void() W_ChangeWeapon =
  955. {
  956.     local    float    it, am, fl;
  957.     
  958.     it = self.items;
  959.     am = 0;
  960.     
  961.     if (self.impulse == 1)
  962.     {
  963.         fl = IT_AXE;
  964.     }
  965.     else if (self.impulse == 2)
  966.     {
  967.         fl = IT_SHOTGUN;
  968.         if (self.ammo_shells < 1)
  969.             am = 1;
  970.     }
  971.     else if (self.impulse == 3)
  972.     {
  973.         fl = IT_SUPER_SHOTGUN;
  974.         if (self.ammo_shells < 2)
  975.             am = 1;
  976.     }        
  977.     else if (self.impulse == 4)
  978.     {
  979.         fl = IT_NAILGUN;
  980.         if (self.ammo_nails < 1)
  981.             am = 1;
  982.     }
  983.     else if (self.impulse == 5)
  984.     {
  985.         fl = IT_SUPER_NAILGUN;
  986.         if (self.ammo_nails < 2)
  987.             am = 1;
  988.     }
  989.     else if (self.impulse == 6)
  990.     {
  991.         fl = IT_GRENADE_LAUNCHER;
  992.         if (self.ammo_rockets < 1)
  993.             am = 1;
  994.     }
  995.     else if (self.impulse == 7)
  996.     {
  997.         fl = IT_ROCKET_LAUNCHER;
  998.         if (self.ammo_rockets < 1)
  999.             am = 1;
  1000.     }
  1001.     else if (self.impulse == 8)
  1002.     {
  1003.         fl = IT_LIGHTNING;
  1004.         if (self.ammo_cells < 1)
  1005.             am = 1;
  1006.     }
  1007.  
  1008.     self.impulse = 0;
  1009.     
  1010.     if (!(self.items & fl))
  1011.     {    // don't have the weapon or the ammo
  1012.         sprint (self, "no weapon.\n");
  1013.         return;
  1014.     }
  1015.     
  1016.     if (am)
  1017.     {    // don't have the ammo
  1018.         sprint (self, "not enough ammo.\n");
  1019.         return;
  1020.     }
  1021.  
  1022. //
  1023. // set weapon, set ammo
  1024. //
  1025.     self.weapon = fl;        
  1026.     W_SetCurrentAmmo ();
  1027. };
  1028.  
  1029. /*
  1030. ============
  1031. CheatCommand
  1032. ============
  1033. */
  1034. void() CheatCommand =
  1035. {
  1036.     if (deathmatch || coop)
  1037.         return;
  1038.  
  1039.     self.ammo_rockets = 100;
  1040.     self.ammo_nails = 200;
  1041.     self.ammo_shells = 100;
  1042.     self.items = self.items | 
  1043.         IT_AXE |
  1044.         IT_SHOTGUN |
  1045.         IT_SUPER_SHOTGUN |
  1046.         IT_NAILGUN |
  1047.         IT_SUPER_NAILGUN |
  1048.         IT_GRENADE_LAUNCHER |
  1049.         IT_ROCKET_LAUNCHER |
  1050.         IT_KEY1 | IT_KEY2;
  1051.  
  1052.     self.ammo_cells = 200;
  1053.     self.items = self.items | IT_LIGHTNING;
  1054.  
  1055.     self.weapon = IT_ROCKET_LAUNCHER;
  1056.     self.impulse = 0;
  1057.     W_SetCurrentAmmo ();
  1058. };
  1059.  
  1060. /*
  1061. ============
  1062. CycleWeaponCommand
  1063.  
  1064. Go to the next weapon with ammo
  1065. ============
  1066. */
  1067. void() CycleWeaponCommand =
  1068. {
  1069.     local    float    it, am;
  1070.     
  1071.     it = self.items;
  1072.     self.impulse = 0;
  1073.     
  1074.     while (1)
  1075.     {
  1076.         am = 0;
  1077.  
  1078.         if (self.weapon == IT_LIGHTNING)
  1079.         {
  1080.             self.weapon = IT_AXE;
  1081.         }
  1082.         else if (self.weapon == IT_AXE)
  1083.         {
  1084.             self.weapon = IT_SHOTGUN;
  1085.             if (self.ammo_shells < 1)
  1086.                 am = 1;
  1087.         }
  1088.         else if (self.weapon == IT_SHOTGUN)
  1089.         {
  1090.             self.weapon = IT_SUPER_SHOTGUN;
  1091.             if (self.ammo_shells < 2)
  1092.                 am = 1;
  1093.         }        
  1094.         else if (self.weapon == IT_SUPER_SHOTGUN)
  1095.         {
  1096.             self.weapon = IT_NAILGUN;
  1097.             if (self.ammo_nails < 1)
  1098.                 am = 1;
  1099.         }
  1100.         else if (self.weapon == IT_NAILGUN)
  1101.         {
  1102.             self.weapon = IT_SUPER_NAILGUN;
  1103.             if (self.ammo_nails < 2)
  1104.                 am = 1;
  1105.         }
  1106.         else if (self.weapon == IT_SUPER_NAILGUN)
  1107.         {
  1108.             self.weapon = IT_GRENADE_LAUNCHER;
  1109.             if (self.ammo_rockets < 1)
  1110.                 am = 1;
  1111.         }
  1112.         else if (self.weapon == IT_GRENADE_LAUNCHER)
  1113.         {
  1114.             self.weapon = IT_ROCKET_LAUNCHER;
  1115.             if (self.ammo_rockets < 1)
  1116.                 am = 1;
  1117.         }
  1118.         else if (self.weapon == IT_ROCKET_LAUNCHER)
  1119.         {
  1120.             self.weapon = IT_LIGHTNING;
  1121.             if (self.ammo_cells < 1)
  1122.                 am = 1;
  1123.         }
  1124.     
  1125.         if ( (self.items & self.weapon) && am == 0)
  1126.         {
  1127.             W_SetCurrentAmmo ();
  1128.             return;
  1129.         }
  1130.     }
  1131.  
  1132. };
  1133.  
  1134. /*
  1135. ============
  1136. ServerflagsCommand
  1137.  
  1138. Just for development
  1139. ============
  1140. */
  1141. void() ServerflagsCommand =
  1142. {
  1143.     serverflags = serverflags * 2 + 1;
  1144. };
  1145.  
  1146. void() QuadCheat =
  1147. {
  1148.     if (deathmatch || coop)
  1149.         return;
  1150.     self.super_time = 1;
  1151.     self.super_damage_finished = time + 30;
  1152.     self.items = self.items | IT_QUAD;
  1153.     dprint ("quad cheat\n");
  1154. };
  1155.  
  1156. /*
  1157. ============
  1158. ImpulseCommands
  1159.  
  1160. ============
  1161. */
  1162. void() ImpulseCommands =
  1163. {
  1164.     local float dir;
  1165.  
  1166.     if (self.impulse >= 1 && self.impulse <= 8)
  1167.         W_ChangeWeapon ();
  1168.  
  1169.     if (self.impulse == 9)
  1170.         CheatCommand ();
  1171.     if (self.impulse == 10)
  1172.         CycleWeaponCommand ();
  1173.     if (self.impulse == 11)
  1174.         ServerflagsCommand ();
  1175.  
  1176.     if (self.impulse == 255)
  1177.         QuadCheat ();
  1178.  
  1179.     if (self.impulse == 160)
  1180.         DisplayCompass();
  1181.         
  1182.     self.impulse = 0;
  1183. };
  1184.  
  1185. /*
  1186. ============
  1187. W_WeaponFrame
  1188.  
  1189. Called every frame so impulse events can be handled as well as possible
  1190. ============
  1191. */
  1192. void() W_WeaponFrame =
  1193. {
  1194.     if (time < self.attack_finished)
  1195.         return;
  1196.  
  1197.     ImpulseCommands ();
  1198.     
  1199. // check for attack
  1200.     if (self.button0)
  1201.     {
  1202.         SuperDamageSound ();
  1203.         W_Attack ();
  1204.     }
  1205. };
  1206.  
  1207. /*
  1208. ========
  1209. SuperDamageSound
  1210.  
  1211. Plays sound if needed
  1212. ========
  1213. */
  1214. void() SuperDamageSound =
  1215. {
  1216.     if (self.super_damage_finished > time)
  1217.     {
  1218.         if (self.super_sound < time)
  1219.         {
  1220.             self.super_sound = time + 1;
  1221.             sound (self, CHAN_BODY, "items/damage3.wav", 1, ATTN_NORM);
  1222.         }
  1223.     }
  1224.     return;
  1225. };
  1226.  
  1227.  
  1228.